ListView Header 와 UpdateObjects 이벤트를 사용하는 방법은?

[예언자]

델파이 11, Android

ListView DynamicAppearance 사용

ListView UpdateObjects를 사용하여 항목을 콘트롤하기를 원함

ListView Header 연결시 에러 발생( Item not found ) -패치이전에는 먹통이었음

Header 연결하지 않으면 정상작동합니다. 방법이 없을까요?

procedure TMainForm.ListView1UpdateObjects(const Sender: TObject; const AItem: TListViewItem);
var X: Integer;
begin
  (Sender as TListView).BeginUpdate;
  var TextItem:=AItem.Objects.DrawableByName('Text1') as TListItemText;
  if Assigned(TextItem) then
  begin
    TryStrToInt(AItem.Data['Text1'].ToString, X);
    if X=0 then TextItem.Text:='0'
    else TextItem.Text:=AItem.Data['Text1'].ToString+'만원';
  end;
  (Sender as TListView).EndUpdate;
end;

Edited 11월 2일, 2021 by 예언자
선언을 잘못

[김원경]

header와  Dynamic Appreance만 사용하실 때는 헤더 정보가 표시가 됩니다. 그러나 제시하신대로   ListView1UpdateObjects 이벤트를 같이 사용하면 item not found 오류가 발생합니다. 다음과 같이 이벤트를 수정하시면  header와 아이템 정보가 다 표시됩니다. 완성된 샘픙을 첨부하오니 참고하시기 바랍니다. ListViewDynamicBG (2).zip

if AItem.Purpose in [TListItemPurpose.Header, TListItemPurpose.Footer] then
 begin
    TextLabel := AItem.Objects.TextObject;
    TextLabel.TextShadowColor := TalphaColorRec.Null;
    TextLabel.Font.Style := [TFontStyle.fsBold, TFontStyle.fsItalic];
 end;

 if not (AItem.Purpose in [TListItemPurpose.Header, TListItemPurpose.Footer]) then
 begin
  TextItem := AItem.Objects.DrawableByName('Text2') as TListItemText;
  ImageItem := AItem.Objects.DrawableByName('Image2') as TListItemImage;

   if Assigned(ImageItem) then
   begin
      if AItem.Data['Text1'].ToString = '김현수' then
        ImageItem.Bitmap := ImageList1.Bitmap(TSizeF.Create(16, 16), 0)
      else
        ImageItem.Bitmap := ImageList1.Bitmap(TSizeF.Create(16, 16), 1);

      ImageItem.Visible := True;
   end;

   if Assigned(TextItem) then
   begin
     if Textitem.Text = '여자' then
       Textitem.Font.Style := [TFontStyle.fsBold, TFontStyle.fsItalic];
    end;
  end;
end;

[결과 이미지]

테스트 해보시고 결과를 댓글로 달아주시면 다른 분들에게도 도움이 될 것입니다 부탁드립니다. 

[예언자]

[해결]

이제 헤더를 사용해도 에러없이 잘됩니다...

정말 감사합니다.

procedure TMainForm.ListView1UpdateObjects(const Sender: TObject; const AItem: TListViewItem);
var 
  X: Integer;
begin
  (Sender as TListView).BeginUpdate;
  if not (AItem.Purpose in [TListItemPurpose.Header, TListItemPurpose.Footer]) then
  begin
    var TextItem:=AItem.Objects.DrawableByName('Text1') as TListItemText;
    if Assigned(TextItem) then
    begin
      if not TryStrToInt(AItem.Data['Text1'].ToString, X) then X:=0;
      if X=0 then TextItem.Text:='0'
      else TextItem.Text:=AItem.Data['Text1'].ToString+'만원';
    end;
  end;
  (Sender as TListView).EndUpdate;
end;

Edited 11월 2일, 2021 by 예언자